/*Program to read CEN1990-003
Census of Population and Housing, 1990:  Summary Tape File 3A

Reads file containing records for summary level 140, selects several 
counties in New York State, reads in selected population, income, and 
housing variables.   Creates 9 county-specific datasets.*/


options ls = 80;
filename county 'U:\ArchiveData\cen1990\003\stf3a140' lrecl=7925;
libname ssd 'U:\users\netid';


data 
	ssd.tioga
	ssd.broome
	ssd.tompkins
	ssd.cortland
	ssd.orange
	ssd.rockland
	ssd.westch
	ssd.dutchess
	ssd.ulster;

infile county;

input state $ 9-10  county 72-74 @;
   if state = 'NY'  and 
       county in (107,007,109,023,071,
                  087,119,027,111) then do;
      input sumlev 11-13
	tractbna $ 52-57
	name $ 192 - 257
	p1 301-309     /*total persons*/
	p4 337-345     /*total families*/
	p5 346-354     /*total households*/
	#2
 	@ 5566 (p80_01 - p80_25) (9.0)   /*household income in 1989*/
	p80a 5791-5799                   /*median household income in 1989*/
        @5800 (p81_01 - p81_02) (15.0)   /*aggregate household income in 1989*/
	#3
	@2848 (p94_01 - p94_02) (9.0)    /*social security income*/
	@2866 (p95_01 - p95_02) (9.)     /*public assistance income*/
	@2884 (p96_01 - p96_02) (9.0)    /*retirement income*/
	p102 2980-2994                   /*aggregate social security income*/ 
	p103 2995-3009                   /*aggregate public assistance income*/
	p104 3010-3024                   /*aggregate retirement income*/
	p107a 3319-3327                  /*median family income in 1989*/
	@4525 (p119_01 - p119_70) (9.)   /*poverty status by race and age*/
        @5155 (p120_01 - p120_14) (9.)   /*poverty status tby age*/
	@5281 (p121_01 - p121_09) (9.)   /*ratio of income to poverty level*/
	#4   
	h1 1381-1389                     /*housing units*/
	@1660 (h10_01 - h10_10) (9.0)    /*tenure by race of householder*/
	@1840 (h12_01 - h12_10) (9.0)    /*tenure by race of householder*/
	@1930 (h13_01 - h13_14) (9.)     /*tenure by age of householder*/
	@2056 (h14_01 - h14_10) (9.)     /*aggregate persons by tenure by race of householder*/
	h43a 4378-4386                   /*median gross rent*/
	h44 4387-4401                    /*aggregate gross rent*/
	@4843 (h47_01 - h47_02) (9.)     /*meals included in rent*/
	@4861 (h48_01 - h48_02) (9.)     /*aggregate gross srent by means included in rent*/
	@4891 (h49_01 - h49_02) (9.0)    /*inclusion of utilities in rent*/
;
   end;
   else delete;

	if county = 107 then output ssd.tioga;
	else if county = 7 then output ssd.broome;
	else if county = 109 then output ssd.tompkins;
	else if county = 23 then output ssd.cortland;
	else if county = 71 then output ssd.orange;
	else if county = 87 then output ssd.rockland;
	else if county = 119 then output ssd.westch;
	else if county = 27 then output ssd.dutchess;
	else if county = 111 then output ssd.ulster;
run;